The DOS Shuffle (backup by going to DOS)

The DOS Shuffle is used when an operation (such as backing up the system) needs to be performed under DOS instead of under Multi-User DOS GOLD on a scheduled basis.

The DOS Shuffle requires 5 files to be created or modified:

1. A LOADER boot text file to load Multi-User DOS GOLD (C:\LOADGOLD)
2. A LOADER boot text file to load DOS (C:\LOADDOS)
3. A batch file executed by the job scheduler under Multi-User DOS GOLD (C:\SHUFFLE.BAT)
4. A batch file to execute the DOS application, executable under DOS (C:\TAPE\TAPE.BAT)
5. Modifications to the existing AUTOEXEC.BAT

A LOADER text file named C:\LOADGOLD used later in AUTOEXEC.BAT to boot Multi-User DOS GOLD: To make this file, copy the existing LOADER.INI file to the name LOADGOLD. Next add the following line in the area headed by the line [BOOT.SYS].

TIMEOUT = 10

                

A LOADER text file named C:\LOADDOS used in SHUFFLE.BAT to boot DOS: To make this file begin again by copying LOADER.INI to the filename LOADDOS. Now modify this file adding the following line in the area headed by the line [standardboot].

TIMEOUT = 10

                

The only difference between the two is the location of the time-out parameter in each file. This is how we can automatically load each operating system when the system is rebooted.

The batch file used by the scheduler sets the system up to boot DOS and then reboots the system. A sample SHUFFLE.BAT would be:

C:
CD \
COPY LOADDOS LOADER.INI
ECHO Doing backups > C:\DOBACKUP
C:\MDOS\SECURITY\REBOOT

                

The scheduler can be started in C:\MDOS\SECURITY\1STBOOT.BAT (if enabled in CONFIG to run , or in one of the INIXXXYY.BAT files. The SHUFFLE.BAT file also needs to be scheduled, and can be done at the same time. Simply include the following line in the desired .BAT file:

SCHEDULE C:\SHUFFLE.BAT ON 1-? EVERY DAY 0200

                

There is one caveat with using the scheduler -- one of the consoles MUST be free and at the system prompt [(USER???) C:>]. This means that if security is being used and all ports are being used, one station needs to be logged in before going home. Another option is to define a "phantom" port that has no terminal attached to it and no handshaking used, but is defined as a multiuser terminal port.

We now modify the AUTOEXEC.BAT file to test for the presence of the DOBACKUP file, and if present execute the tape backup batch file. Insert the following lines into the existing AUTOEXEC.BAT file:

REM	The majority of AUTOEXEC.BAT goes before here
REM	If an EXIT command or menuing system is used,
REM	make sure it happens AFTER this text
REM
REM	Check to see if we need to do a backup by the presence
REM	of the DOBACKUP file
IF NOT EXIST DOBACKUP GOTO SKIPBACK
REM
REM	The TAPE.BAT batch file contains that actual commands to
REM	perform the tape backup. A log file is HIGHLY recommended.
CALL C:\TAPE\TAPE.BAT
REM
REM	Delete the "flag file" we used to signify backups needed
DEL C:\DOBACKUP
REM
REM	The next few steps use LOADER to change our boot
REM	destination so we will boot into CCI Concurrent DOS
C:
CD \
DEL LOADER.INI
COPY LOADGOLD LOADER.INI
REM
REM	This next step will reboot the machine
C:\MDOS\SECURITY\REBOOT.COM
REM
REM	Any additional commands that need to be executed if
REM	backups are not being done should be placed after this
REM	label
:SKIPBACK